!大伙看看，有何問題，如何改進(jìn)？
!100*80*10基巖上澆筑混凝土50*40*10，每三天澆筑1米高（第一天澆完，剩下兩天窩工），
!共用一個(gè)月時(shí)間,分為十層（layer)澆筑，模型、條件均為假設(shè)
!建模
/filename,test
/PREP7
BLOCK,,50,,10,,40,
BLOCK,-25,75,-10,0,-20,60
ET,1,70
LSEL,S,,,9,12,1
LESIZE,ALL,,,10
LSEL,S,,,21,24,1
LESIZE,ALL,,,20
LSEL,S,,,2,4,2
LSEL,A,,,5,7,2
LESIZE,ALL,,,10
LSEL,S,,,14,16,2
LSEL,A,,,17,19,2
LESIZE,ALL,,,20
LSEL,S,,,1,3,2
LSEL,A,,,6,8,2
LESIZE,ALL,,,10
LSEL,S,,,13,15,2
LSEL,A,,,18,20,2
LESIZE,ALL,,,5
allsel
MP,DENS,1,2400.0 !混凝土材料
MP,KXX ,1,300.89
MP,C,1,0.94500
MAT,1
VMESH,1
MP,DENS,2,2600.0 !基巖材料
MP,KXX ,2,300.89
MP,C,2,0.94500
MAT,2
VMESH,2
nummrg,all
!熱分析
/SOLU
NROPT,FULL !Specifies the Newton-Raphson options in full transient analysis
ESEL,S,MAT,,2 !MAT2 IS 基巖
NSLE,S
IC,all,TEMP,16.4, !加基巖初溫
ASEL,S,,,7,9,1
ASEL,A,,,11,12,1
NSLA,S,1
SF,all,HFLUX,0 !加基巖絕熱邊界條件
NSEL,S,LOC,Y,-0.1,0.1
ASEL,S,,,3
NSLA,U,1
SF,ALL,CONV,2016,20 !加基巖第三邊界條件（和空氣接觸面）
!加初始條件
ALLSEL,ALL
ESEL,U,MAT,,2
NSLE,S
EKILL,ALL !KILL 混凝土
IC,all,TEMP,35, !混凝土澆筑時(shí)溫度為35度
ANTYPE,TRANSIENT,new !分析類型
!日子的流逝
*DO,LAYER,1,10,1
!激活第N層單元
ALLSEL,ALL
NSEL,S,LOC,Y,(LAYER-1),LAYER !第一層從Y=0~1米，第二層從Y=1~2米,...
ESLN,S ,1
EALIVE,ALL
*DO,DAY,LAYER*3-2,LAYER*3,1 !每三天澆筑一層
ALLSEL,ALL
ASEL,S,,,1,2,1
ASEL,A,,,5,6,1
NSLA,S,1
NSEL,R,LOC,Y,0,LAYER
NSEL,A,LOC,Y,LAYER-0.1,LAYER+0.1
SF,ALL,CONV,2016,20 !加混凝土第三類對(duì)流邊界條件
*DO,LOOP,1,LAYER,1
ALLSEL,ALL
NSEL,R,LOC,Y,LOOP-1,LOOP
ESLN,S,1
TDAY=DAY-(LOOP-1)*3 !已經(jīng)完工的天數(shù)
HE00=47880*(TDAY/(0.862+TDAY)-(TDAY-1)/(0.862+TDAY-1))
BFE,ALL,HGEN, ,HE00 !加水化熱
*ENDDO
!計(jì)算設(shè)置
ALLSE
TRNOPT,FULL
LUMPM,0
TIME,DAY
AUTOTS,0
DELTIM,1, , ,1
KBC,0
TSRES,ERASE
OUTRES,ALL,ALL,
SOLVE
*ENDDO
ESEL,S,MAT,,1
NSLE,S,
SFEDELE,ALL,ALL,CONV !刪對(duì)流邊界條件
SFDELE,ALL,CONV
*ENDDO
FINISH
!結(jié)構(gòu)分析
/PREP7
ET,1,SOLID65 !變熱單元為結(jié)構(gòu)單元
*DIM,EXX,ARRAY,30 !考慮變化的EX
EXX(1)=0.325E10,0.57778E10,0.78E10,0.94545E10,0.10833E11,0.12E11,0.13E11,0.13867E11,0.14625E11,0.15294E11, 0.15889E11, 0.1642E11 ,0.169E11, 0.17333E11, 0.17727E11, 0.18087E11,0.18417E11,0.1872E11
EXX(19)=0.190E11, 0.19259E11, 0.195E11, 0.19724E11, 0.19933E11, 0.20129E11,0.20312E11, 0.20485E11, 0.20647E11, 0.208E11, 0.20944E11, 0.21081E11
*DO,I,1,30,1 !定義材料，混凝土澆筑完每過一天變一種材料
MP,DENS,I,2400
MP,EX,I,EXX(I)
MP,PRXY,I,0.167
MP,ALPX,I,0.9E-5
MP,REFT,I,15
*ENDDO
MP,DENS,31,2600 !定義基巖材料
MP,EX,31,0.20800E+11
MP,PRXY,31,0.167
MP,ALPX,31,0.9E-5
ESEL,S,MAT,,,2
MPCHG,31,ALL, !!變熱材料為結(jié)構(gòu)材料
ALLSEL
/SOLU
NROPT,FULL !Specifies the Newton-Raphson options in a full transient analysis
NLGEOM,ON
NSLA,S,,,7,9,1
NSLA,A,,,11,12,1
D,all,ALL !加基巖約束
!KILL THE CONCRETE ELEMENT
ESEL,U,MAT,,1
NSLE,S
EKILL,ALL !KILL 混凝土
*DO,DAY,1,30,1 !隨時(shí)間改變，變換材料
*DO,LAYER,1,10
*IF,DAY,GT,LAYER*3-3,THEN
NSEL,S,LOC,Y,LAYER-1,LAYER
ESLN,S,1
EALIVE,ALL !ACTIVE NEXT LAYER
MPCHG,DAY-(LAYER-1)*3,ALL, !CHANG MAT
ALLSEL,ALL
*ENDIF
*ENDDO
ALLSEL,ALL
ACEL,0,0,-9.8, !GRAVITY LOAD
LDREAD,TEMP,,,DAY, ,'TEST','rth',' ' !TEMP LOAD Reads results from the results file and applies them as loads.
CNVTOL,F, ,0.2,2,200, !Sets convergence values for nonlinear analyses.
TIME,DAY
AUTOTS,0
DELTIM,1, , ,1
KBC,0
TSRES,ERASE !Defines an array of keytimes at which the time-stepping strategy changes
OUTRES,ALL,ALL,
SOLVE
*ENDDO
!1、定義重力集散地是應(yīng)為正值：ACEL,0,0,9.8
!2、砼單元邊長(zhǎng)（1*4*5）相差5倍，對(duì)計(jì)算精度的影響會(huì)不會(huì)較大？
!3、熱單元SOLID70對(duì)應(yīng)的結(jié)構(gòu)單元為SOLID45，改為SOLID65是否合適？
!4、原分析得到的結(jié)果與實(shí)際情況比較如何？
!5、如何體現(xiàn)氣溫的變化？
